Etiket: asp.net

PHP’nin dahili fonksiyonları olan file_get_contents ve file_put_contents basitçe dosya okuma ve dosyaya veri yazma işleri için çokça tercih edilir. file_get_contents 1. parametresinde belirtilen dosyayı okuyarak bir değişkene geri döndürür. file_put_contents birinci parametrede belirtilen dosya adına, ikinci parametre ile verilen veriyi yazar. Aşağıdaki  file_put_contents kodunun 3. parametresinde yer alan append verinin yazılacağı dosyaya ekleme mi yapılacak yoksa verilen veri ile yeni bir dosya mı oluşturulacak sorusunu cevaplar. Append (ekle) true ise 2. parametredeki veri dosyanın sonuna eklenir değilse dosya boş olarak oluşturulduktan sonra veri yazılır. Dosyanın içerisinde sadece belirtilen veri bulunmuş olur, önceki veri kaybolur.

<%
Function File_Get_Contents(strFile)
	' Remote File
	If Left(strFile, 7) = "http://" Or Left(strFile, 8) = "https://" Then
		Set objXML = Server.CreateObject("Microsoft.XMLHTTP")
		' Use this line if above errors
		'Set objXML = Server.CreateObject("MSXML2.ServerXMLHTTP")
		objXML.Open "GET", strFile, False
		objXML.Send()
		File_Get_Contents = objXML.ResponseText()
		Set objXML = Nothing
	' Local File
	Else
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		Set objFile = objFSO.OpenTextFile(strFile, 1)
		File_Get_Contents = objFile.ReadAll()
		Set objFile = Nothing
		Set objFSO = Nothing
	End If
End Function

Function File_Put_Contents(strFile, strContents, blnAppend)
	If blnAppend Then
		intMode = 8
	Else
		intMode = 2
	End If
	Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
	Set objFile = objFSO.OpenTextFile(strFile, intMode, True)
	objFile.Write(strContents)
	Set objFile = Nothing
	Set objFSO = Nothing
End Function
%>